main()
{
	rotate_obj = getentarray("atomic_rotate","targetname");
	if(isdefined(rotate_obj))
		for(i=0;i<rotate_obj.size;i++)
			rotate_obj[i] thread nuketown_go_rotate();
			
	windfx = loadfx ("props/car_glass_large");
	windtrigs = getentarray("windtrig","targetname");
	for(j=0;j<windtrigs.size;j++)
		windtrigs[j] thread dowindow(j,windfx);			
}


nuketown_go_rotate()
{
	if (!isdefined(self.speed))
		self.speed = 25.0;
	if (!isdefined(self.script_noteworthy))
		self.script_noteworthy = "z";
 
	for(;;)
	{
		// rotateYaw(float rot, float time, <float acceleration_time>, <float deceleration_time>);
		if (self.script_noteworthy == "z")
			self rotateYaw(360,self.speed);
		else if (self.script_noteworthy == "x")
			self rotateRoll(360,self.speed);
		else if (self.script_noteworthy == "y")
			self rotatePitch(360,self.speed);
		wait (self.speed-0.1); // removes the slight hesitation that waittill("rotatedone"); gives.
		// self waittill("rotatedone");
	}
}
	

dowindow(windnumber,windfx)
{
	window = getent(self.target,"targetname");
	totaldamage=0;
	targetdamage=100;
	windowbroken=0;
	broken = getentarray("brokenwindow"+(windnumber+1),"targetname");
	for(j=0;j<broken.size;j++)
	{
		broken[j] notsolid();
		broken[j] hide();
	}
	window show();
	while(!windowbroken)
	{
		self waittill ("damage",amount);
		totaldamage+=amount;
		if(totaldamage>targetdamage)
			windowbroken=1;
	}
    self playsound( "bo2nuketown_glass" );
	PlayFX(windfx, self.origin );
	for(j=0;j<broken.size;j++)
		broken[j] show();
	window delete();
	self delete();
}